home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 1 / Cream of the Crop 1.iso / PROGRAM / ZTIMER11.ARJ / PZTIME.BAT < prev    next >
DOS Batch File  |  1992-04-20  |  2KB  |  49 lines
  1. @echo off
  2. rem
  3. rem ***************************************************************
  4. rem * Batch file PZTIME.BAT, which builds and runs the precision  *
  5. rem * Zen Timer program PZTEST.EXE to time the code named as the  *
  6. rem * command-line parameter. To time the code in MOVTST.ASM,     *
  7. rem * type the DOS command:                                       *
  8. rem *                                                             *
  9. rem * pztime movtst.asm                                           *
  10. rem *                                                             *
  11. rem * Note that TASM and TLINK must be in the current directory   *
  12. rem * or on the current path in order for this batch file to      *
  13. rem * work.                                                       *
  14. rem ***************************************************************
  15. rem
  16. rem Make sure a file to test was specified
  17. rem
  18. if not x%1==x goto ckexist
  19. echo ***************************************************************
  20. echo * Please specify a file to test.                              *
  21. echo ***************************************************************
  22. goto end
  23. rem
  24. rem Make sure the file exists.
  25. rem
  26. :ckexist
  27. if exist %1 goto docopy
  28. echo ***************************************************************
  29. echo * The specified file, "%1," doesn't exist
  30. echo ***************************************************************
  31. goto end
  32. rem
  33. rem copy the file to measure to TESTCODE
  34. rem
  35. :docopy
  36. copy %1 testcode
  37. tasm pztest;
  38. if errorlevel 1 goto errorend
  39. tlink pztest+pztimer;
  40. if errorlevel 1 goto errorend
  41. pztest
  42. goto end
  43. :errorend
  44. echo ****************************************************************
  45. echo * An error occurred while building the precision Zen timer.    *
  46. echo ****************************************************************
  47. :end
  48.  
  49.